这个要领能够把全部文件夹打包到xml文件中，把这个xml文件文件和解包文件放在一同后，运转解包文件就能够把本来的文件开释出来，如许我们就能够把网站打包上传到虚拟主机，再运转解包文件就能够了。我在当地测试之挑选了少部分文件，不知在文件许多的状况实行效力怎样。
实在完成的思绪也很简单，重要应用的是xml文件能够寄存二进制数据的道理。有兴致的朋侪能够下载下面的附件研讨下！！
解包文件
代码以下:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%> <% Option Explicit %> <% On Error Resume Next %> <% Response.Charset="UTF-8" %> <% Server.ScriptTimeout=99999999 %>
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>剧本之家——文件解包顺序_www.jb51.net</title>
</head>
<body>
<%
Dim strLocalPath
'获得当前文件夹的物理途径
strLocalPath=Left(Request.ServerVariables("PATH_TRANSLATED"),InStrRev(Request.ServerVariables("PATH_TRANSLATED"),"\"))
Dim objXmlFile
Dim objNodeList
Dim objFSO
Dim objStream
Dim i,j
Set objXmlFile = Server.CreateObject("Microsoft.XMLDOM")
objXmlFile.load(Server.MapPath("update.xml"))
If objXmlFile.readyState=4 Then
If objXmlFile.parseError.errorCode = 0 Then
Set objNodeList = objXmlFile.documentElement.selectNodes("//folder/path")
Set objFSO = CreateObject("Scripting.FileSystemObject")
j=objNodeList.length-1
For i=0 To j
If objFSO.FolderExists(strLocalPath & objNodeList(i).text)=False Then
objFSO.CreateFolder(strLocalPath & objNodeList(i).text)
End If
Response.Write "建立目次" & objNodeList(i).text & "<br/>"
Response.Flush
Next
Set objFSO = nothing
Set objNodeList = nothing
Set objNodeList = objXmlFile.documentElement.selectNodes("//file/path")
j=objNodeList.length-1
For i=0 To j
Set objStream = CreateObject("ADODB.Stream")
With objStream
.Type = 1
.Open
.Write objNodeList(i).nextSibling.nodeTypedvalue
.SaveToFile strLocalPath & objNodeList(i).text,2
Response.Write "开释文件" & objNodeList(i).text & "<br/>"
Response.Flush
.Close
End With
Set objStream = Nothing
Next
Set objNodeList = nothing
End If
End If
Set objXmlFile = Nothing
response.write "文件解包终了"
%>
</body>
</html>
pack.asp 打包文件
代码以下:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%> <% Option Explicit %> <% On Error Resume Next %> <% Response.Charset="UTF-8" %> <% Server.ScriptTimeout=99999999 %>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>文件打包顺序_剧本之家_www.jb51.net</title>
</head>
<body>
<%
Dim ZipPathDir,ZipPathFile
Dim startime,endtime
'在此更改要打包文件夹的途径
ZipPathDir = "D:\testasp\dictionary\xmlPacked\scrollColor"'
ZipPathFile = "update.xml"
if right(ZipPathDir,1)<>"\" then ZipPathDir=ZipPathDir&"\"
'最先打包
CreateXml(ZipPathFile)
'遍历目次内的一切文件以及文件夹
sub LoadData(DirPath)
dim XmlDoc
dim fso 'fso对象
dim objFolder '文件夹对象
dim objSubFolders '子文件夹鸠合
dim objSubFolder '子文件夹对象
dim objFiles '文件鸠合
dim objFile '文件对象
dim objStream
dim pathname,TextStream,pp,Xfolder,Xfpath,Xfile,Xpath,Xstream
dim PathNameStr
response.Write("=========="&DirPath&"==========<br>")
set fso=server.CreateObject("scripting.filesystemobject")
set objFolder=fso.GetFolder(DirPath)'建立文件夹对象
Response.Write DirPath
Response.flush
Set XmlDoc = Server.CreateObject("Microsoft.XMLDOM")
XmlDoc.load Server.MapPath(ZipPathFile)
XmlDoc.async=false
'写入每一个文件夹途径
set Xfolder = XmlDoc.SelectSingleNode("//root").AppendChild(XmlDoc.CreateElement("folder"))
Set Xfpath = Xfolder.AppendChild(XmlDoc.CreateElement("path"))
Xfpath.text = replace(DirPath,ZipPathDir,"")
set objFiles=objFolder.Files
for each objFile in objFiles
if lcase(DirPath & objFile.name) <> lcase(Request.ServerVariables("PATH_TRANSLATED")) then
Response.Write "---<br/>"
PathNameStr = DirPath & "" & objFile.name
Response.Write PathNameStr & ""
Response.flush
'================================================
'写入文件的途径及文件内容
set Xfile = XmlDoc.SelectSingleNode("//root").AppendChild(XmlDoc.CreateElement("file"))
Set Xpath = Xfile.AppendChild(XmlDoc.CreateElement("path"))
Xpath.text = replace(PathNameStr,ZipPathDir,"")
'建立文件流读入文件内容，并写入XML文件中
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Type = 1
objStream.Open()
objStream.LoadFromFile(PathNameStr)
objStream.position = 0
Set Xstream = Xfile.AppendChild(XmlDoc.CreateElement("stream"))
Xstream.SetAttribute "xmlns:dt","urn:schemas-microsoft-com:datatypes"
'文件内容采纳二制体式格局寄存
Xstream.dataType = "bin.base64"
Xstream.nodeTypedValue = objStream.Read()
set objStream=nothing
set Xpath = nothing
set Xstream = nothing
set Xfile = nothing
'================================================
end if
next
Response.Write "<p>"
XmlDoc.Save(Server.Mappath(ZipPathFile))
set Xfpath = nothing
set Xfolder = nothing
set XmlDoc = nothing
'建立的子文件夹对象
set objSubFolders=objFolder.Subfolders
'挪用递归遍历子文件夹
for each objSubFolder in objSubFolders
pathname = DirPath & objSubFolder.name & "\"
LoadData(pathname)
next
set objFolder=nothing
set objSubFolders=nothing
set fso=nothing
end sub
'建立一个空的XML文件，为写入文件作预备
sub CreateXml(FilePath)
'顺序最先实行时候
startime=timer()
dim XmlDoc,Root
Set XmlDoc = Server.CreateObject("Microsoft.XMLDOM")
XmlDoc.async = False
Set Root = XmlDoc.createProcessingInstruction("xml","version='1.0' encoding='UTF-8'")
XmlDoc.appendChild(Root)
XmlDoc.appendChild(XmlDoc.CreateElement("root"))
XmlDoc.Save(Server.MapPath(FilePath))
Set Root = Nothing
Set XmlDoc = Nothing
LoadData(ZipPathDir)
'顺序完毕时候
endtime=timer()
response.Write("页面实行时候：" & FormatNumber((endtime-startime),3) & "秒")
end sub
%>
</body>
</html>
以上就是在asp下经由过程xml打包网站文件的要领的细致内容，更多请关注ki4网别的相干文章！
