旗下导航:搜·么
当前位置:网站首页 > XML教程 > 正文

应用XML开辟留言板简朴的实例代码剖析【XML教程】,XML,留言板

作者:搜教程发布时间:2019-11-27分类:XML教程浏览:73评论:0


导读:xml是一种基于文本格式的元标记言语,它注意对数据结构和数据意义的形貌,完成了数据内容和显现款式的星散(xml+xsl),而且是与平台无关的。因为XML注意数据内容的形貌,...
xml是一种基于文本格式的元标记言语,它注意对数据结构和数据意义的形貌,完成了数据内容和显现款式的星散(xml+xsl),而且是与平台无关的。

因为XML注意数据内容的形貌,因此,关于数据的检索异常有意义,我们不会再象HTML那样,检索出与我们请求无关的信息。

另一方面,XML文件是数据的载体,应用XML作为数据库,不需要接见任何数据库系统,我们能够运用恣意WEB手艺来显现我们的数据,比方HTML,FlashMX 等。

因为天下各大计算机公司的积极参与,XML正日趋成为基于互联网的数据格式新一代的规范。

下面应用XML作为数据的载体,开辟一个基于XML的留言板。

起首,我们竖立XML文件guestbook.xml,该文件纪录了留言者的姓名、电子邮件、网址、留言内容。固然,我们也能够根据需要增加恣意多的信息。文件内容以下:

<?xml version="1.0" encoding="gb2312"?> 
<留言本> 
<留言纪录> 
<留言者姓名>KAI</留言者姓名> 
<电子邮件>kai@hostx.org</电子邮件> 
<网址>http://www.17xml.com </网址> 
<留言内容>千山万水老是情,常来泡妞行不行?咔咔:_)</留言内容> 
</留言纪录> 
</留言本> 
 

  因为现在很多服务器都支撑asp,我们采纳罕见的ASP来作为完成的东西,guestbook.asp文件以下:

<%@Language="VBScript"%> 
<% 
'设置Web页面的信息 
Response.Buffer = true 
Response.Expires = -1 
  
'显现留言函数init() 
'www.knowsky.com
Function init() 
entryForm() 
  
'定义局部变量 
Dim objXML 
Dim arrNames 
Dim arrEmails 
Dim arrURLS 
Dim arrMessages 
  
'建立XMLDOM文档对象,用来寄存留言 
Set objXML = server.createObject("Msxml2.DOMDocument") 
objXML.async = false 
objXML.load(server.MapPath("guestbook.xml")) 
  
'获得留言本各元素的鸠合 
Set arrNames = objXML.getElementsByTagName("留言者姓名") 
Set arrEmails = objXML.getElementsByTagName("电子邮件") 
Set arrURLS = objXML.getElementsByTagName("网址") 
Set arrMessages = objXML.getElementsByTagName("留言内容") 
  
Response.Write "<table border='0' width='100%'>" 
Response.Write "<tr><td bgcolor='#00CCFF' align='center' height='26'>" 
Response.Write "<b>列位的留言以下:</b>" 
Response.Write "</td></tr>" 
  
'输出留言本各元素的内容,最新的留言先显现 
For x=arrNames.length-1 To 0 Step -1 
Response.Write "<tr><td><a href=mailto:" & arrEmails.item(x).text & ">" & arrNames.item(x).text & "</a></td></tr>" 
Response.Write "<tr><td>网址:<a href=" & arrURLS.item(x).text & " target='_blank'>" & arrURLS.item(x).text & "</a><td></tr>" 
Response.Write "<tr><td>留言内容:</td></tr>" 
Response.Write "<tr><td bgcolor='#0099ff'>" & arrMessages.item(x).text &"</td></tr>" 
Response.Write "<tr><td> </td></tr>" 
Next 
  
Response.Write "</table>" 
Set objXML = nothing 
End Function 
  
'向XML文件增加留言纪录的函数addEntry() 
Function addEntry() 
  
'定义局部变量 
Dim strName 
Dim strEmail 
Dim strURL 
Dim strMessage 
  
'获得留言表单的输入内容 
strName = Request.Form("姓名") 
strEmail = Request.Form("电子邮件") 
strURL = Request.Form("网址") 
strMessage = Request.Form("留言") 
  
Dim objXML 
Dim objEntry 
Dim objName 
Dim objEmail 
Dim objURL 
Dim objMessage 
  
'向XML文件增加留言内容 
Set objXML = server.createObject("Msxml2.DOMDocument") 
objXML.async = false 
objXML.load(server.MapPath("guestbook.xml")) 
  
Set objEntry = objXML.createNode("element", "留言纪录", "") 
objXML.documentElement.appendChild(objEntry) 
  
Set objName = objXML.createNode("element", "留言者姓名", "") 
objEntry.appendChild(objName) 
objName.text = strName 
  
Set objEmail = objXML.createNode("element", "电子邮件", "") 
objEntry.appendChild(objEmail) 
objEmail.text = strEmail 
  
Set objURL = objXML.createNode("element", "网址", "") 
objEntry.appendChild(objURL) 
objURL.text = strURL 
  
Set objMessage = objXML.createNode("element", "留言内容", "") 
objEntry.appendChild(objMessage) 
objMessage.text = strMessage 
  
objXML.save(server.MapPath("guestbook.xml")) 
  
Response.Redirect("guestbook.asp") 
  
End function 
  
'填写和发送留言表单的函数entryForm() 
Function entryForm() 
  
Response.Write "<p align='center'><b>XML 留言本 例子</b></p>" 
Response.Write "<hr color='#000099' width='100%' noshade>" 
Response.Write "<form action=guestbook.asp?action=addEntry method=post>" 
Response.Write "<table border=1>" 
Response.Write "<tr><td>您的姓名:</td><td><input type=text name=姓名 /></td></tr>" 
Response.Write "<tr><td>电子邮件:</td><td><input type=text name=电子邮件 /></td></tr>" 
Response.Write "<tr><td>您的网址:</td><td><input type=text name=网址 /></td></tr>" 
Response.Write "<tr><td>您的留言:</td><td><textarea name=留言 cols=40 rows=5></textarea></td></tr>" 
Response.Write "<tr><td> </td><td><input type=submit value=宣布留言 /></td></tr>" 
Response.Write "</table>" 
Response.Write "</form>" 
  
End Function 
%> 
<html> 
<head> 
<title>XML 留言例子</title> 
<meta http-equiv="Content-Type" content="text/html; charset=gb2312"> 
</head> 
<body> 
<% 
'推断是不是发送了留言,并更新留言信息 
Dim a 
a = Request.Querystring("action") 
If a<>"" Then 
addEntry 
else 
init 
End If 
%> 
</body> 
</html>

以上是应用XML开辟留言板简朴的例子,完全是举一反三,能够根据需要举行增加更多的功用,一切顺序在WIN2000+IIS5.0+IE5.5调试经由过程.

以上就是应用XML开辟留言板简朴的实例代码剖析的内容,更多相关内容请关注ki4网(www.ki4.cn)!

标签:XML留言板


欢迎 发表评论: